Кого-нибудь она еще интересует?
Есть так сказать, Pinger 2.0 Beta - код переписан с нуля, добавлены некоторые фишки (проверка наличия подключения, слежение за входящим трафом...)
Копируем содержимое в блокнот, сохраняем как pinger.cmd
choice.com бросаем либо в папку со скриптом, либо в папку system32 (что будет правильнее)
Скрипты link.vbs и traf.vbs бросаем в папку со скриптом.
Внимание: для нормальной работы скрипта должна быть запущена служба "Маршрутизация и удаленный доступ" (пуск - настройка - панель управления - администрирование - службы, маршрутизация и удаленный доступ: тип запуска - авто)
Для моторов можно сообразить перезагрузку телефона (обычно этим мтс страдает - иногда только помогает перезагрузка тела, чтоб подключится), для лайфовского zte - перерегистрацию симки в сети.
Есть так сказать, Pinger 2.0 Beta - код переписан с нуля, добавлены некоторые фишки (проверка наличия подключения, слежение за входящим трафом...)
Код:
@echo off
set link="giga"
set phone="*99***1#"
set pause=30
set host=google.com.ua
set TimeoutMin=1000
set TimeoutMax=10000
set Try=1
set MinPing=3
set MaxPing=15
rem ***traf****************************
:traf
if exist link del link
set LNK=
ipconfig > link
link.vbs
for /f %%i in (link) do set LNK=%%i
if not defined LNK goto connect
if not %LNK%==ok goto connect
echo LINK ACTIVE...
if exist traf del traf
set Rx1=
set Rx2=
netsh.exe interface ip show interface > traf
traf.vbs
for /f %%i in (traf) do set Rx1=%%i
if not defined Rx1 goto connect
echo %Rx1%
choice /n /T:Y,2 > nul
if exist traf del traf
netsh.exe interface ip show interface > traf
traf.vbs
for /f %%i in (traf) do set Rx2=%%i
if not defined Rx2 goto connect
echo %Rx2%
if %Rx1%==%Rx2% (
goto ping
) else (
goto ok
)
rem ***traf****************************
rem ***ping****************************
:ping
echo.
echo START PING #%Try%
ping %host% -n 1 -w %TimeoutMin%
if not errorlevel 1 goto ok
set /a Try=%Try%+1
if %Try% gtr %MinPing% goto ForcePing
goto ping
rem ***ping****************************
rem ***Forceping***********************
:ForcePing
echo.
echo START FORCE PING #%Try%
ping %host% -n 1 -w %TimeOutMax%
if not errorlevel 1 goto ok
set /a Try=%Try%+1
if %Try% gtr %MaxPing% goto connect
goto ForcePing
rem ***Forceping***********************
rem ***connect*************************
:connect
set /a Try=1
echo.
echo DISCONNECTING...
rasdial %link% /disconnect
choice /n /T:Y,3 > nul
echo CONNECTING...
rasdial %link%
rem /phone:%phone%
if %errorlevel% neq 0 (
echo %errorlevel%
goto connect
)
goto ping
if errorlevel 0 goto ok
rem ***connect*************************
rem ***ok*****************************
:ok
echo.
echo ALL RIGHT
set /a Try=1
goto end
rem ***ok*****************************
rem ***end****************************
:end
set /a Try=1
echo.
choice /C:PRDE /T:P,%Pause% /N Pause %Pause%s. [P]ing [R]econnect [D]isconnect [E]xit?
rem echo.
rem echo.
goto %ERRORLEVEL%
:1
goto traf
:2
goto connect
:3
rasdial %link% /disconnect
:4
goto exit
rem ***end****************************
rem ***exit***************************
:exit
rem ***exit***************************choice.com бросаем либо в папку со скриптом, либо в папку system32 (что будет правильнее)
Скрипты link.vbs и traf.vbs бросаем в папку со скриптом.
Внимание: для нормальной работы скрипта должна быть запущена служба "Маршрутизация и удаленный доступ" (пуск - настройка - панель управления - администрирование - службы, маршрутизация и удаленный доступ: тип запуска - авто)
Для моторов можно сообразить перезагрузку телефона (обычно этим мтс страдает - иногда только помогает перезагрузка тела, чтоб подключится), для лайфовского zte - перерегистрацию симки в сети.
Останнє редагування:
